Vista a todos los jugadores

Sección para misiones y edición ArmA III

Moderador: C. Misiones & Noticias

Avatar de Usuario
<A2>Bhelma
Soldado A2
Soldado A2
Mensajes: 1314
Registrado: 17 Dic 2010, 14:37

Re: Vista a todos los jugadores

Mensaje por <A2>Bhelma »

<A2>Pescadorr escribió: 15 Mar 2023, 16:19 Aqui lo tienes prueba a ver si te va bien:

Código: Seleccionar todo

call
{
	_flag = this; 
	_afterCommand = {}; 

	_fncOwnFlag = 
	{ 
		params ["_winSide"]; 
		_flagPath = "\a3\data_f\flags\%1.paa"; 
		_fileFlag = switch _winSide do 
		{ 
			case west: {"flag_nato_co"}; 
			case east: {"flag_csat_co"}; 
			case independent: {"flag_aaf_co"}; 
			default {"flag_FIA_CO"} 
		}; 
		format [_flagPath,_fileFlag]; 
	};
	_actionParams = ["_flag", "_caller", "_actionId", "_arguments"]; 

	[_flag, 1] remoteExec ["setflagAnimationPhase"];
	_colorflag = (civilian call _fncOwnFlag);
	[_flag, _colorflag] remoteExec ["setFlagTexture"]; 
	_flag setVariable ["TER_flagSide",civilian,true]; 
	_icon = "\a3\ui_f\data\igui\cfg\holdactions\holdaction_takeoff2_ca.paa"; 
	_duration = 10; 
	_addID = 
	[
		_flag, "Cambiar Bandera", _icon, _icon, 
		"_target getVariable [""TER_flagSide"",civilian] != side _this", 
		"true", 
		{}, 
		{ 
			params ["_flag", "_caller", "_actionId", "_arguments","_progress","_maxProgress"]; 
			_arguments params ["_actionParams","_fncOwnFlag","_afterCommand"]; 
			_relProgress = _progress/_maxProgress; 
			if (_relProgress < 0.5) then 
			{ 
				[_flag, 1-(2*_relProgress)] remoteExec ["setflagAnimationPhase"];
			} else { 
				if (_relProgress == 0.5) then 
				{
					_colorflag = (side _caller call _fncOwnFlag);
					[_flag, _colorflag] remoteExec ["setFlagTexture"]; 
				}; 
				[_flag, ((2*_relProgress)-1)] remoteExec ["setflagAnimationPhase"];
			}; 
		}, 
		{ 
			params ["_flag", "_caller", "_actionId", "_arguments"]; 
			_arguments params ["_actionParams","_fncOwnFlag","_afterCommand"]; 
			_flag setVariable ["TER_flagSide",side _caller, true]; 
			[] call _afterCommand; 
			BH_OBJx = true ; 
			publicVariable "BH_OBJx";
		}, 
		{ 
			params ["_flag", "_caller", "_actionId", "_arguments"]; 
			_arguments params ["_actionParams","_fncOwnFlag","_afterCommand"]; 
			[_flag, 1] remoteExec ["setflagAnimationPhase"];
			_side = _flag getVariable ["TER_flagSide",civilian]; 
			_colorflag = (_side call _fncOwnFlag);
			[_flag, _colorflag] remoteExec ["setFlagTexture"];
		}, 
		[_actionParams,_fncOwnFlag,_afterCommand], 
		_duration, 
		1.5, 
		false
	] call BIS_fnc_holdActionAdd; 

	_addID
};
Joer tío....muchísimas gracias.

A ver si pillo a alguien esta noche y lo pruebo
Imagen
Imagen

Avatar de Usuario
<A2>Bhelma
Soldado A2
Soldado A2
Mensajes: 1314
Registrado: 17 Dic 2010, 14:37

Re: Vista a todos los jugadores

Mensaje por <A2>Bhelma »

Gracias Pesca, ahora sii funciona.

Gracias :bravo: :bravo:
Imagen
Imagen

Responder