¿Cómo se usa la cámara?

Foro de vídeos de Misiones y Vídeo Tutoriales
Avatar de Usuario
<A2>Pepe
Soldado A2
Soldado A2
Mensajes: 1618
Registrado: 12 Ago 2013, 21:48

¿Cómo se usa la cámara?

Mensaje por <A2>Pepe »

Pues en estos días de calor se me ha despertado la vena artística y me he puesto a mirar cómo se hacen cinemáticas (horrible palabro) en el Arma 3.

La verdad no he encontrado información actualizada y clara para lo que yo quería. Hay muchas opciones utilizando por ejemplo Cámara Splendid (ESC en juego y cámara) o GCam, que pueden ser útiles. Dependen del movimiento del ratón y no me gusta el efecto con el Parkinsons dominante. Yo quería lo básico, seleccionar una posición de cámara y grabar, cambiar la posición o el objetivo a grabar, etc.

Así que después de dedicar una tarde, una calurosa tarde, al asunto me he aclarado un poco con el tema. Como también la edad fomenta el Alzheimer lo dejo por aquí para acordame, que gasto memoria de pez, y puede que le sea útil a alguien.

La información básica la obtuve de

https://community.bistudio.com/wiki/Cat ... ra_Control

y del hilo de Armados que me picó la curiosidad

viewtopic.php?f=108&t=16262

La utilización de la cámara es muy sencilla una vez te aclaras un poco. Hay que crear una cámara, darle una posición y objetivo y grabar hasta cambiar posición y objetivo. Entre posición y posición se puede establecer una transición de tiempo. También se pueden hacer otras modificaciones como la apertura o el cambio del campo de visión. Lo mejor es grabar una escena y después otra repitiendo el proceso. La IA nunca hace lo mismo (sería la desesperación de cualquier director) y cuanto más larga sea la escena más posibilidades de que se vaya al carajo. Después montas los distintos fragmentos para hacer el vídeo.

Lo más complicado puede ser definir las posiciones globales o relativas de la cámara. Yo lo he solucionado con Cámara Splendid que te deja copiar al portapapeles (CTRL + X) la posición y características del enfoque de cámara.

["Paste",["Stratis",[1824.19,5493.24,0.352788],352.329,0.75,[-3.86101,0],0,0,727.314,0.3,0,1,0,1]] call bis_fnc_camera;

Te copia esta información de la que nos interesa la posición global de la cámara.

[1824.19,5493.24,0.352788]

Pues no me enrollo más. Aquí dejo el archivo init.sqf para hacer la grabación (aunque se puede hecer con un activador o lógica o lo que necesites) que coloco dentro de la carpeta de la misión y la misión de la grabación. Así se puede ir viendo cada paso (recuerda que he utilizado nombres para los objetos Hombre1, Bandera, etc. hay que cambiarlos según proceda) . La grabación es muy sosa pero creo sirve para ilustrar el proceso. Después cada uno que le añada creatividad e imaginación.

Código: Seleccionar todo

/*Creación de una cámara y su movimiento para creación de escenas*/



//Creamos la cámara en una posición nula
_camera = "camera" camCreate [0,0,0];

//Preparamos la fijación del objetivo de la cámara en Hombre1
_camera camPrepareTarget Hombre1;

//Preparamos la posición de la cámara en el objeto Bandera 
_camera camPreparePos getPos Bandera;

//Visión de la camara (efectos)
_camera cameraEffect ["internal", "back"];

//Quitamos las barras negras arriba y abajo que aparecen por defecto (si no funciona dar a reiniciar misión y va, cosas del arma)
showCinemaBorder false;

//Determinamos el tiempo de la transición, en este caso inmediato 0
_camera camCommitPrepared 0;
waitUntil { camCommitted _camera };



//Preparamos la nueva posición de la cámara
//En este caso hemos puesto una posición global que podemos obtener fácilmente con Splendid Camera 
_camera camPreparePos [4005.18,7321.54,15.67501];

//Determinamos el tiempo de la transición, en este caso 30, tiempo que tardará la cámara en moverse de la anterior posición a esta.
_camera camCommitPrepared 30;
waitUntil { camCommitted _camera };



//Mantenemos la cámara es esta posición tiempo 25
sleep 25;



//Nueva posición cámara y tiempo transición
_camera camPreparePos [3968.04,7500.29,13.5455];
_camera camCommitPrepared 50;
waitUntil { camCommitted _camera };



sleep 40;



//Ahora cambiamos la fijación del objetivo de la cámara en el tanque y la posición de la cámara con transición 50
_camera camPrepareTarget Tank1;
_camera camPreparePos [3568.04,7300.29,23.5455];
_camera camCommitPrepared 50;
waitUntil { camCommitted _camera };



sleep 70;




//Colocamos la cámara en uno de los aviones con transición 5 con fijación del objetivo en el otro
_camera camPrepareTarget Avion1;
_camera camPreparePos getPos Avion2;
_camera camCommitPrepared 5;
waitUntil { camCommitted _camera };
_camera attachTo [Avion2, [5, -10, 1.50]];



sleep 150;



//Destruimos la cámara y volvemos al muñequito del jugador
_camera cameraEffect ["terminate", "back"];
camDestroy _camera;


Aquí dejo la misión

https://drive.google.com/open?id=1cwbrz ... 9_ODBCB4UF

y aquí el vídeo grabado con esta configuración de cámara

Y ahora vivo aquí donde cruza la frontera, entre la razón y una inútil ilusión traicionera.
Imagen
Imagen Imagen Imagen Imagen

Responder