Script Halo_Pescadorr

Sección para misiones y edición ArmA III

Moderador: C. Misiones & Noticias

Responder
<A2>Rutius
Soldado A2
Soldado A2
Mensajes: 646
Registrado: 11 Abr 2018, 13:38

Script Halo_Pescadorr

Mensaje por <A2>Rutius »

// ***Script By PESCADORR ***

null=[]spawn
{
{
if (local _x) then //filtramos por localidades
{
[_x] spawn // creamos ejecuciones paralelas, una por cada unidad jugable
{
_unit = _this select 0;
if (!isNull (unitBackpack _unit)) then // comprobamos que tiene mochila
{
private ["_helmet","_Vclass","_Varray","_Barray","_Bclass","_mochila"];
_helmet = headgear _unit;
_Vclass = vest _unit;
_Varray = vestItems _unit;
_Barray = backpackItems _unit;
_Bclass = backpack _unit;
sleep 0.1;
_mochila = createVehicle ["groundWeaponHolder", [0,0,0], [], 0, "can_collide"]; // creamos la mochila
_mochila addBackpackCargoGlobal [_Bclass, 1];
_unit addVest "V_RebreatherB"; //añadimos atuendo y paracaidas
_unit addBackpack "B_Parachute";
_unit addHeadgear "H_PilotHelmetFighter_B";
_unit addGoggles "G_Combat";

waitUntil {animationState _unit == "HaloFreeFall_non"}; //espera hasta que empiece en caida libre
_mochila attachTo [_unit,[-0.5,0.1,-1.1],"RightFoot"];
_mochila setVectorDirAndUp [[0,-1,-0.05],[0,0,-1]];

waituntil
{
if ((animationState _unit == "HaloFreeFall_non") && ((getPos _unit select 2) < distancia)) then //sino esta abierto el paracaidas y esta por debajo de 2500
{
_unit action ["OpenParachute", _unit];
};
animationState _unit == "para_pilot"
}; //espera a que el paraidas ya este abierto
_mochila attachTo [vehicle _unit,[-0.1,0.45,-0.75],"RightFoot"];
_mochila setVectorDirAndUp [[0,-0.2,-1],[0,1,0]];

waitUntil {isTouchingGround _unit || (getPos _unit select 2) < 1}; //espera a tocar el suelo
detach _mochila;
deleteVehicle _mochila;
sleep 0.1;
_unit addvest _Vclass; //devolvemos equipacion
sleep 0.1;
{ _unit addItemToVest _x } foreach _Varray;
sleep 0.1;
_unit addBackpack _Bclass;
sleep 0.1;
{ _unit addItemToBackpack _x } foreach _Barray;
sleep 0.1;
_unit addHeadgear _helmet;
} else //sino tiene mochila
{
private ["_helmet","_Vclass","_Varray"];
_helmet = headgear _unit;
_Vclass = vest _unit;
_Varray = vestItems _unit;

_unit addVest "V_RebreatherB"; //añadimos atuendo y paracaidas
_unit addBackpack "B_Parachute";
_unit addHeadgear "H_PilotHelmetFighter_B";
_unit addGoggles "G_Combat";

waitUntil {animationState _unit == "HaloFreeFall_non"}; //espera hasta que empiece en caida libre

waituntil
{
if ((animationState _unit == "HaloFreeFall_non") && ((getPos _unit select 2) < distancia)) then //sino esta abierto el paracaidas y esta por debajo de 2500
{
_unit action ["OpenParachute", _unit];
};
animationState _unit == "para_pilot"
}; //espera a que el paraidas ya este abierto

waitUntil {isTouchingGround _unit || (getPos _unit select 2) < 1}; //espera a tocar el suelo
_unit addvest _Vclass; //devolvemos equipacion
sleep 0.1;
{ _unit addItemToVest _x } foreach _Varray;
sleep 0.1;
_unit addHeadgear _helmet;
sleep 0.1;
};
};
[_x] spawn // spawn strobos solo humanos y lideres llevan strobo
{
if (!nocturna) exitwith {};
_unit2 = _this select 0;
if ((isplayer _unit2) && ((leader _unit2) == _unit2)) then
{
private ["_obj1", "_light1"]; //_Nombreplayer = [name _unit2] call BIS_fnc_filterString;
_light1 = 'B_IRStrobe' createVehicle [0,0,0];
_light1 attachTo [_unit2,[0,0,0.20],'head'];
sleep 1;
_obj1 = nearestObjects [_light1, ["all"], 2];
sleep 1;
waituntil { animationState _unit2 == "para_pilot" };
_light1 attachTo [vehicle _unit2,[0,0,0.84],'head'];
waitUntil { isTouchingGround _unit2 || (getPos _unit2 select 2) < 1};
{
if (typeOf _x == 'NVG_TargetC') then
{
deletevehicle _x;
};
} foreach _obj1;
};
};
};
} foreach playableunits; //poner playableunits para misiones, o allunits para editor
};
if (isserver) exitwith{}; //filtramos solo player (poner como comentario para ver en el editor)

[] spawn // spawn audio
{
waitUntil {animationState player == "HaloFreeFall_non"};
waituntil
{
playSound "flapping";
sleep 4.2;
animationState player == "para_pilot" && alive player
};
playSound "open_chute";
sleep 3;
waituntil
{
playSound "para_pilot";
sleep 4.2;
(getpos player select 2) < 2 && alive player
};
sleep 1;
playSound "close_chute";
};

waitUntil {sleep 0.5;animationState player == "para_pilot"};
setAperture 0.05;
setAperture -1;
"DynamicBlur" ppEffectEnable true;
"DynamicBlur" ppEffectAdjust [8.0];
"DynamicBlur" ppEffectCommit 0.01;
sleep 1;
"DynamicBlur" ppEffectAdjust [0.0];
"DynamicBlur" ppEffectCommit 3;
sleep 3;
"DynamicBlur" ppEffectEnable false;
"RadialBlur" ppEffectAdjust [0.0, 0.0, 0.0, 0.0];
"RadialBlur" ppEffectCommit 1.0;
"RadialBlur" ppEffectEnable false;
waitUntil {isTouchingGround player || (getPos player select 2) < 1};
cutText ["", "BLACK FADED", 999];
sleep 5;
cutText ["", "BLACK IN", 2];
Ningún plan perfecto sobrevive al primer contacto con el enemigo

Avatar de Usuario
<A2>Valquiria
Soldado A2
Soldado A2
Mensajes: 1605
Registrado: 02 May 2016, 21:40

Re: Script Halo_Pescadorr

Mensaje por <A2>Valquiria »

Podrías explicar que aporta? O como funciona.

Salud2
:A2:
Imagen
https://www.youtube.com/channel/UC2C6xl ... w5KuFe6RhQ
義 勇 慈悲 礼儀 誠 名誉 忠誠

<A2>Rutius
Soldado A2
Soldado A2
Mensajes: 646
Registrado: 11 Abr 2018, 13:38

Re: Script Halo_Pescadorr

Mensaje por <A2>Rutius »

<A2>Valquiria escribió: 30 Jun 2021, 22:29 Podrías explicar que aporta? O como funciona.

Salud2
:A2:
Es un script de Pesca que equivale al Backpack on Chest pero sin el engorro de que siga funcionando una vez llegado a tierra. Lo he pegado aquí porque tenía una duda y Pesca me dijo que lo pusiera en un post para ver la línea concreta que había que cambiar para que sólo afectara a unas escuadras y no a todos los jugadores.
Ningún plan perfecto sobrevive al primer contacto con el enemigo

Avatar de Usuario
<A2>Flac0
Visitante
Mensajes: 1609
Registrado: 22 Mar 2020, 18:07

Re: Script Halo_Pescadorr

Mensaje por <A2>Flac0 »

Lo robo !!!
Imagen

<A2>Rutius
Soldado A2
Soldado A2
Mensajes: 646
Registrado: 11 Abr 2018, 13:38

Re: Script Halo_Pescadorr

Mensaje por <A2>Rutius »

<A2>Flac0 escribió: 30 Jun 2021, 22:47 Lo robo !!!

De todas formas ya estaba en el foro, en un post de Pesca.
Ningún plan perfecto sobrevive al primer contacto con el enemigo

Responder